/***********************************************************************************************************/
/***********************************************************************************************************/
*This do-file produces Figure 3 ("Maturity and Covenants")
* 
*Input
*- Master_Dealscan.dta
/***********************************************************************************************************/
/***********************************************************************************************************/


/****************************************************************/
/**********   0. Intros   ***************************************/
/****************************************************************/
set more off
global path "C:\Users\tobia\Dropbox\6_WIP Papers\Trends in Corporate Borrowing"

/****************************************************************/
/**********   1. Graph for the U.S.  *****************************/
/****************************************************************/

	use 	"$path/2_IntermediateFiles/Master_Dealscan.dta", clear
			
		keep if Country == "USA"
		keep if BaseRate == "LIBOR"
		keep if inlist(Currency, "United States Dollars")
					
		table leveraged igrade, c(sum FacilityAmt)
		table leveraged igrade, c(count FacilityAmt)
		
		keep if leveraged != . & igrade != . /*Market segment information missing*/
		drop if leveraged == 0 & igrade == 0 /*Loan classified as both not igrade and not leveraged*/
		drop if leveraged == 1 & igrade == 1 /*Loan classified as both igrade and leveraged*/
		
		collapse (mean) Maturity nCovenant covlite [aweight=FacilityAmt], by(year igrade)
			
		#d ;
		twoway 	(line Maturity year if igrade == 1, color(black))
				(line Maturity year if igrade == 0, color(black) lpattern(dash))
				,graphregion(fcolor(white) lcolor(white) ifcolor(white) ilcolor(white))
					legend(pos(6) ring(50) col(1) size(small) order (1 "Average Maturity (IG)" 2 "Average Maturity (Leveraged)"))
					title("Maturity")
					xtitle("Year")
					xlabel(2002(1)2019, labsize(small) angle(vertical)) xmtick(2002(1)2019, nolabels ticks) 
					ytitle("Average Maturity in years")
					ylabel(0(0.5)6, labsize(small) angle (horizontal) nogrid) 
					name(A, replace)
			;
		#d cr
		
		#d ;
		twoway 	(line nCovenant year if igrade == 1, color(black)  yaxis(1) )
				(line nCovenant year if igrade == 0, color(black) lpattern(dash) yaxis(1))
				(line covlite year if igrade == 0, color(gs12) yaxis(2))
				,graphregion(fcolor(white) lcolor(white) ifcolor(white) ilcolor(white))
					legend(pos(6) ring(50) col(1) size(vsmall) order (1 "Average No. of Covenants (IG)" 2 "Average No. of Covenants (Leveraged)" 3 "Covenant-lite (Leveraged)"))
					title("Covenants")
					xtitle("Year")
					xlabel(2002(1)2019, labsize(small) angle(vertical)) xmtick(2002(1)2019, nolabels ticks) 
					ytitle("Number of Covenants", axis(1))
					ytitle("Pct. of Covenant-lite Loans", axis(2))
					ylabel(0(0.5)3, labsize(small) angle(horizontal) nogrid axis(1))
					ylabel(0(0.1)0.5, labsize(small) angle(horizontal) nogrid axis(2))				
					name(B, replace)
			;
		#d cr
		
		graph combine A B, graphregion(fcolor(white) lcolor(white) ifcolor(white) ilcolor(white))
		
		graph		export "$path/3_Results/Figure3.pdf", replace
	
		*Values as table
		table year igrade, c(mean nCovenant) format(%9.2f)
		table year igrade, c(mean covlite) format(%9.2f)
	
	
/****************************************************************/
/**********   2. Graph for Europe.  *****************************/
/****************************************************************/

	use 	"$path/2_IntermediateFiles/Master_Dealscan.dta", clear
			
		*Sample (similar as for US, but with additional restrictions on base rate and currency)
		keep if inlist(Country, "Austria", "Belgium", "Germany", "Finland", "France", "Greece", "Ireland", "Italy", "Luxembourg") | inlist(Country, "Netherlands", "Portugal", "Spain")	
		*keep if inlist(BaseRate, "LIBOR", "Euribor")
		keep if inlist(Currency, "Euro", "United Kingdom Pounds", "United States Dollars")
							
		table leveraged igrade, c(sum FacilityAmt)
		table leveraged igrade, c(count FacilityAmt)
		
		keep if leveraged != . & igrade != . /*Market segment information missing*/
		drop if leveraged == 0 & igrade == 0 /*Loan classified as both not igrade and not leveraged*/
		drop if leveraged == 1 & igrade == 1 /*Loan classified as both igrade and leveraged*/
		
		collapse (mean) Maturity nCovenant covlite [aweight=FacilityAmt], by(year igrade)
			
		#d ;
		twoway 	(line Maturity year if igrade == 1, color(black))
				(line Maturity year if igrade == 0, color(black) lpattern(dash))
				,graphregion(fcolor(white) lcolor(white) ifcolor(white) ilcolor(white))
					legend(pos(6) ring(50) col(1) size(small) order (1 "Average Maturity (IG)" 2 "Average Maturity (Leveraged)"))
					title("Maturity")
					xtitle("Year")
					xlabel(2002(1)2019, labsize(small) angle(vertical)) xmtick(2002(1)2019, nolabels ticks) 
					ytitle("Average Maturity in years")
					ylabel(0(0.5)8, labsize(small) angle (horizontal) nogrid) 
					name(A, replace)
			;
		#d cr
		
		#d ;
		twoway 	(line nCovenant year if igrade == 1, color(black)  yaxis(1) )
				(line nCovenant year if igrade == 0, color(black) lpattern(dash) yaxis(1))
				(line covlite year if igrade == 0, color(gs12) yaxis(2))
				,graphregion(fcolor(white) lcolor(white) ifcolor(white) ilcolor(white))
					legend(pos(6) ring(50) col(1) size(vsmall) order (1 "Average No. of Covenants (IG)" 2 "Average No. of Covenants (Leveraged)" 3 "Covenant-lite (Leveraged)"))
					title("Covenants")
					xtitle("Year")
					xlabel(2002(1)2019, labsize(small) angle(vertical)) xmtick(2002(1)2019, nolabels ticks) 
					ytitle("Number of Covenants", axis(1))
					ytitle("Pct. of Covenant-lite Loans", axis(2))
					ylabel(0(0.5)3, labsize(small) angle(horizontal) nogrid axis(1))
					ylabel(0(0.1)0.5, labsize(small) angle(horizontal) nogrid axis(2))				
					name(B, replace)
			;
		#d cr
		
		graph combine A B, graphregion(fcolor(white) lcolor(white) ifcolor(white) ilcolor(white))
		
		graph		export "$path/3_Results/Figure3 (Europe).pdf", replace